PW-GUI/build.gradle at dev · AmberIsFrozen/PW-GUI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
plugins {
    id 'java'
    id 'edu.sc.seis.launch4j' version '4.0.0'
    alias libs.plugins.shadow
}

group = 'com.lx862'
version = properties.version

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io/' }
}

dependencies {
    testImplementation platform('org.junit:junit-bom:6.0.2')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
    implementation libs.common.cli
    implementation libs.common.io
    implementation libs.bundles.flatlaf
    implementation libs.bundles.commonmark
    implementation libs.gson
    implementation libs.toml4j
    implementation libs.bundles.imageio.ext
    implementation libs.rsyntaxtextarea
    implementation libs.ztzip
    implementation libs.slf4j.noop
}

tasks.withType(JavaCompile).configureEach {
    options.release = 17
}

jar {
    enabled = false
    archiveFileName = "${rootProject.name}-v${rootProject.version}-nodep.jar"
    manifest {
        attributes(
            'Main-Class': 'com.lx862.pwgui.Main'
        )
    }
}

launch4j {
    mainClassName = 'com.lx862.pwgui.Main'
    icon = "${projectDir}/assets/pwgui_icon.ico"
    outfile = "${rootProject.name}-v${project.version}.exe"
    errTitle = "This program requires at least Java 17 to run"
    downloadUrl = "https://adoptium.net/"
    jreMinVersion = "17.0.0"
    fileDescription = "Lightweight GUI Wrapper around packwiz, a Minecraft modpack tool."
    copyright = "AmberFrost"
    jarTask = project.tasks.shadowJar
}

build {
    dependsOn(shadowJar)
}

processResources {
    inputs.property "name", rootProject.name
    inputs.property "version", rootProject.version
    inputs.property "author", rootProject.properties.author

    filesMatching("build.json") {
        expand(
            "name": inputs.properties.name,
            "version": inputs.properties.version,
            "author": inputs.properties.author
        )
    }
}

shadowJar {
    archiveFileName = "${rootProject.name}-v${rootProject.version}.jar"
}

test {
    useJUnitPlatform()
}