hmcnc/meson.build at master · ChaissonLab/hmcnc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
project(
  'hmcnc',
  ['cpp', 'c'],
  version : '0.0.1',
  default_options : [
    'buildtype=release',
    'warning_level=3',
    'cpp_std=c++14',
    'c_std=c11',
    'b_ndebug=if-release'],
  license : 'MIT',
  meson_version : '>= 0.52.0',
)

############
# CXXFLAGS #
############

hmcnc_warning_flags = []
cpp = meson.get_compiler('cpp')
foreach cflag: [
  '-Wduplicated-cond',
  '-Wduplicated-branches',
  '-Wlogical-op',
  '-Wrestrict',
  '-Wnull-dereference',
  '-Wuseless-cast',
  '-Wdouble-promotion',
  '-Wshadow',
  '-Wformat=1',
  ]
  if cpp.has_argument(cflag)
      hmcnc_warning_flags += cflag
  endif
endforeach

hmcnc_cpp_args = hmcnc_warning_flags

################
# dependencies #
################

# boost
boost_dep = dependency('boost', required : true, include_type : 'system')

# threads
threads_dep = dependency('threads', required : true)

# htslib
htslib_dep = dependency('htslib', required : true, version : '>=1.4', fallback : ['htslib', 'htslib_dep'])

# zlib
zlib_dep = dependency('zlib', required : true, fallback : ['zlib', 'zlib_dep'])

hmcnc_lib_deps = [
  boost_dep,
  threads_dep,
  zlib_dep,
  htslib_dep,
]

#####################
# sources + library #
#####################

# only for unit tests, not main  exe
hmcnc_include_directories = include_directories('include')

subdir('src')
subdir('tests')