richenv/flake.nix at master · DavSanchez/richenv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
{
  description = "richenv - Rich environment variable setup for Haskell";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = with inputs; [
        git-hooks.flakeModule
        treefmt-nix.flakeModule
      ];

      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      perSystem =
        {
          config,
          pkgs,
          ...
        }:
        {
          treefmt = {
            programs = {
              nixfmt = {
                enable = true; # Nix
                excludes = [ "default.nix" ]; # Generated by cabal2nix
              };
              cabal-fmt.enable = true; # Cabal
              ormolu.enable = true; # Haskell
            };
          };

          pre-commit = {
            check.enable = true;
            settings = {
              package = pkgs.prek;
              hooks = {
                actionlint.enable = true;
                cabal2nix.enable = true;
                convco.enable = true;
                hlint.enable = true;
                hpack.enable = true;
                treefmt = {
                  enable = true;
                  packageOverrides.treefmt = config.treefmt.build.wrapper;
                };
              };
            };
          };

          devShells.default = pkgs.mkShell {
            shellHook = ''
              ${config.pre-commit.installationScript}
              echo 1>&2 "Welcome to the development shell!"
            '';
            nativeBuildInputs = config.pre-commit.settings.enabledPackages;

            buildInputs = with pkgs.haskellPackages; [
              ghc
              cabal-install
              haskell-language-server
              hspec-discover
            ];
          };

          packages = {
            default = pkgs.haskellPackages.callPackage ./default.nix { };

            richenv-ghc96 = pkgs.haskell.packages.ghc96.callPackage ./default.nix { };
            richenv-ghc98 = pkgs.haskell.packages.ghc98.callPackage ./default.nix { };
            richenv-ghc910 = pkgs.haskell.packages.ghc910.callPackage ./default.nix { };
            richenv-ghc912 = pkgs.haskell.packages.ghc912.callPackage ./default.nix { };
            richenv-ghc914 = pkgs.haskell.packages.ghc914.callPackage ./default.nix { };
          };
        };
    };
}