luajava/build.gradle at main · LuaLink/luajava · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
group 'party.iroiro.luajava'
version(System.getenv('IS_RELEASE') == 'true' ? '4.0.2' : '4.0.8-SNAPSHOT')


repositories {
    mavenLocal()
    mavenCentral()
}


// Only keep desktop subprojects, remove android and android-test from build
subprojects { it ->
    if (!['android', 'android-test', 'jpms-example'].contains(it.name)) {
        apply plugin: 'java'

        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(8)
            }

            withSourcesJar()
            withJavadocJar()
        }
    }
}

ext {
    jdk = JavaVersion.current().majorVersion
    jdkJavadoc = "https://docs.oracle.com/javase/8/docs/api/"
    println "JDK Javadoc link for this build is ${rootProject.jdkJavadoc}"
}

apply from: 'publish.gradle'
apply from: 'jacoco.gradle'

tasks.register('allJavadoc', Javadoc) {
    Set<String> projects = [
            'lua51',
            'lua52',
            'lua53',
            'lua54',
            'luajit',
            'luaj',
            'luajava',
    ]
    source subprojects
            .findAll { projects.contains(it.name) }
            .collect { it.sourceSets.main.allJava }
    classpath = files(subprojects.findAll { projects.contains(it.name) }
            .collect { it.sourceSets.main.compileClasspath })
    exclude(
            '**/party/iroiro/luajava/util/**',
            '**/party/iroiro/luajava/cleaner/**',
    )
    destinationDir = file("${buildDir}/docs/javadoc")
}