Notations.java/build.gradle.kts at main · MeMyselfMirai/Notations.java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id("java-library")
    id("maven-publish")
    id("signing")
}

group = "io.github.ad417"
version = "0.1.0"

repositories {
    mavenCentral()
}

dependencies {
    implementation("io.github.ad417:BreakInfinity:0.2.0")
    implementation("org.jetbrains:annotations:24.0.0")

    testImplementation(platform("org.junit:junit-bom:5.9.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

tasks.test {
    useJUnitPlatform()
}

signing {
    // require(true)
    configure<SigningExtension> {
        useInMemoryPgpKeys(
                project.findProperty("SIGNING_KEY") as String,
                project.findProperty("SIGNING_PASSWORD") as String
        )
        sign(publishing.publications)
    }
}

publishing {

    configure<JavaPluginExtension> {
        withJavadocJar()
        withSourcesJar()
    }

    configure<PublishingExtension> {
        publications {
            val main by creating(MavenPublication::class) {
                from(components["java"])

                pom {
                    name.set("BreakNotations")
                    description.set(
                            "A Java port of AntimatterDimensions-Notations - all the notations used in the web game \"Antimatter Dimensions\", for use in other applications. "
                    )
                    url.set("https://github.com/AD417/Notations.java")
                    licenses {
                        license {
                            name.set("MIT")
                            url.set("https://opensource.org/licenses/MIT")
                        }
                    }
                    developers {
                        developer {
                            id.set("AD417")
                            name.set("Alexander Day")
                            email.set("ard8302@rit.edu")
                        }
                    }
                    scm {
                        connection.set("scm:git:git@github.com:AD417/Notations.java.git")
                        url.set("https://github.com/AD417/Notations.java")
                    }
                }
            }
        }
        repositories {
            maven {
                name = "OSSRH"
                setUrl("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
                credentials {
                    username = project.findProperty("OSSRH_USER") as String
                    password = project.findProperty("OSSRH_PASSWORD") as String
                }
            }
        }
    }
}