GradlePlus/build.gradle at development · MinecraftPlus/GradlePlus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
plugins {
    id 'groovy'
    id 'groovy-gradle-plugin'
    id 'maven-publish'
}

group 'org.minecraftplus.gradle'
version '0.1.0'

java.toolchain {
    languageVersion = JavaLanguageVersion.of(8)
}

sourceSets {
    assetator
}

dependencies {
    implementation gradleApi()
}

configurations {
    assetatorImplementation.extendsFrom implementation
}

jar {
    sourceSets.each {set ->
        from set.output
    }
}

gradlePlugin {
    plugins {
        assetator {
            id = 'org.minecraftplus.gradle.assetator'
            displayName = 'Assetator'
            description = 'Plugin that allows generating minecraft asset index from resource list'
            implementationClass = 'org.minecraftplus.gradle.assetator.AssetatorPlugin'
        }
    }
}

publishing {
    repositories {
        maven {
            name = "minecraftplus"
            url = "https://maven.minecraftplus.org"
            allowInsecureProtocol = false

            if (project.version.toString().endsWith("-SNAPSHOT")) {
                url = url.toString().concat("/snapshots")
            } else {
                url = url.toString().concat("/releases")
            }

            // To know how use credentials see https://docs.gradle.org/current/samples/sample_publishing_credentials.html
            credentials(PasswordCredentials)
            authentication {
                basic(BasicAuthentication)
            }
        }
    }
}