klint/flake.nix at trunk · Rust-for-Linux/klint · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      rust-overlay,
      treefmt-nix,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        inherit (nixpkgs) lib;
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };

        toolchain = (builtins.fromTOML (builtins.readFile ./rust-toolchain.toml)).toolchain;
        rustc = pkgs.rust-bin.fromRustupToolchain toolchain;
      in
      {
        devShells.rustup = pkgs.mkShell {
          buildInputs = with pkgs; [ sqlite ];
          nativeBuildInputs = with pkgs; [ rustup ];
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [ sqlite ];
          nativeBuildInputs = [
            (pkgs.rust-bin.fromRustupToolchain (
              toolchain // { components = toolchain.components ++ [ "rust-analyzer" ]; }
            ))
          ];
        };

        packages.default =
          (pkgs.rustPlatform.buildRustPackage.override {
            inherit rustc;
            cargo = rustc;
          })
            {
              pname = "klint";
              version = "0.1.0";

              src = lib.fileset.toSource {
                root = ./.;
                fileset = lib.fileset.unions [
                  ./Cargo.toml
                  ./Cargo.lock
                  ./build.rs
                  ./.cargo
                  ./src
                ];
              };
              cargoLock = {
                lockFile = ./Cargo.lock;
                outputHashes = {
                  "compiletest_rs-0.11.2" = "sha256-kjdqn9MggFypzB6SVWAsNqD21wZYiv+dtPvyGNi/Wqo=";
                };
              };

              buildInputs = with pkgs; [ sqlite ];
              doCheck = false;

              # If kernel rustdoc tests are enabled, user would need a matching version of rustdoc.
              # klint provides a klint-rustdoc binary to ease the process. However, for nix, we already
              # know the path to the rustdoc binary, so just symlink and replace the wrapper.
              postInstall = ''
                ln -sf "${lib.getExe' rustc "rustdoc"}" $out/bin/klint-rustdoc
              '';

              passthru.rustc = rustc;
            };

        apps = {
          latest-rustc = {
            type = "app";
            program = "${pkgs.writers.writeBash "latest-rustc" ''
              echo ${pkgs.rust-bin.nightly.latest.rustc.version} | grep -Po 'nightly.*'
            ''}";
          };

          update-rustc = {
            type = "app";
            program = "${pkgs.writers.writeBash "update-rustc" ''
              nix flake update
              sed -i "s/channel = .*/channel = \"$(nix run .#latest-rustc)\"/" rust-toolchain.toml
            ''}";
          };
        };

        formatter = (treefmt-nix.lib.evalModule pkgs ./treefmt.nix).config.build.wrapper;
      }
    );
}