mkprompt/flake.nix at main · TextQLLabs/mkprompt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
{
  description = "MkPrompt";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    nix-npm-buildpackage.url = "github:serokell/nix-npm-buildpackage";
  };

  outputs = { self, nixpkgs, nix-npm-buildpackage, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        haskellPackages = pkgs.haskell.packages.ghc92;

        packageName = "mkprompt";

        frontend = nix-npm-buildpackage.legacyPackages.x86_64-linux.buildNpmPackage
            rec {
              src = ./frontend;
              installPhase =
                ''
                    runHook preInstall
                    mkdir $out
                    cp -r ./build/* $out
                    runHook postInstall
                '';
              npmBuild = "npm run build";
          };

        pkg = isDev: haskellPackages.developPackage {
            root = ./backend;
            returnShellEnv = isDev;
            modifier = drv: if isDev
                then pkgs.haskell.lib.addBuildTools drv (with haskellPackages;
                    [ cabal-install
                      pkgs.nodejs
                      ormolu
                      pkgs.postgresql
                    ])
                else drv;
            };

        mkDocker = args: pkgs.dockerTools.buildImage {
            name = "mkprompt";
            config = {
                Cmd = args;
                ExposedPorts = {
                    "4080/tcp" = {};
                };
            };
        };

      in {
        packages.${packageName} = pkg false;
        packages.dockerImage = mkDocker [
          "${pkg false}/bin/mkprompt"
          "--static-file-dir" "${frontend}"
        ];
        packages.frontend = frontend;
        devShell = pkg true;
      });
}