CR

Author: dzbarsky

cc/toolchains/impl/nested_args.bzl

@@ -294,19 +294,21 @@ def _escape(s):
 
 _SUPPORTED_BUILD_SETTING_TYPES = ["string", "bool", "int", "Label"]
 
-def _format_build_setting(target, fail = fail):
-    value = target[BuildSettingInfo].value
-
+def _format_build_setting(value, label, fail = fail):
     if type(value) in _SUPPORTED_BUILD_SETTING_TYPES:
         return _escape(str(value))
 
-    fail("%s had an unsupported build setting type %s. Only string, bool, int, or Label values may be formatted." % (target.label, type(value)))
+    fail("%s had an unsupported build setting type %s. Only string, bool, int, or Label values may be formatted." % (label, type(value)))
 
 def _format_target(target, fail = fail):
     if VariableInfo in target:
         return "%%{%s}" % target[VariableInfo].name
     elif BuildSettingInfo in target:
-        return _format_build_setting(target, fail = fail)
+        return _format_build_setting(
+            target[BuildSettingInfo].value,
+            target.label,
+            fail = fail,
+        )
     elif DirectoryInfo in target:
         return _escape(target[DirectoryInfo].path)
 

tests/rule_based_toolchain/analysis_test_suite.bzl

@@ -33,15 +33,25 @@ def analysis_test_suite(name, tests, targets = [_DEFAULT_TARGET]):
     targets = [native.package_relative_label(target) for target in targets]
 
     test_case_names = []
-    for test_name, impl in tests.items():
+    for test_name, test in tests.items():
         if not test_name.endswith("_test"):
             fail("Expected test keys to end with '_test', got test case %r" % test_name)
         test_case_names.append(":" + test_name)
+        config_settings = {}
+        if type(test) == "struct":
+            if not hasattr(test, "impl"):
+                fail("Expected struct tests to define an 'impl' field, got %r" % test_name)
+            impl = test.impl
+            if hasattr(test, "config_settings"):
+                config_settings = test.config_settings
+        else:
+            impl = test
         analysis_test(
             name = test_name,
             impl = impl,
             provider_subject_factories = FACTORIES,
             targets = {label.name: label for label in targets},
+            config_settings = config_settings,
         )
 
     native.test_suite(

tests/rule_based_toolchain/args/BUILD

@@ -5,6 +5,7 @@ load("//cc/toolchains/impl:variables.bzl", "cc_variable", "types")
 load("//tests/rule_based_toolchain:analysis_test_suite.bzl", "analysis_test_suite")
 load("//tests/rule_based_toolchain:testing_rules.bzl", "expect_failure_test")
 load(":args_test.bzl", "TARGETS", "TESTS")
+load(":override_args.bzl", "override_args")
 
 cc_variable(
     name = "some_variable",
@@ -70,6 +71,12 @@ util.helper_target(
     format = {"min_os_flag": ":macos_min_os_flag"},
 )
 
+override_args(
+    name = "build_setting_format_override",
+    target = ":build_setting_format",
+    value = "-mmacosx-version-min=13.0",
+)
+
 util.helper_target(
     cc_args,
     name = "with_dir",

tests/rule_based_toolchain/args/args_test.bzl

@@ -50,6 +50,7 @@ _SIMPLE_FILES = [
     "tests/rule_based_toolchain/testdata/multiple2",
 ]
 _TOOL_DIRECTORY = "tests/rule_based_toolchain/testdata"
+_OVERRIDDEN_MIN_OS = "-mmacosx-version-min=13.0"
 
 _CONVERTED_ARGS = subjects.struct(
     flag_sets = subjects.collection,
@@ -190,12 +191,34 @@ def _build_setting_format_test(env, targets):
         flag_groups = [flag_group(flags = ["-mmacosx-version-min=12.0"])],
     )])
 
+def _build_setting_format_override_test(env, targets):
+    build_setting = env.expect.that_target(targets.build_setting_format_override).provider(ArgsInfo)
+    build_setting.actions().contains_exactly([
+        targets.c_compile.label,
+        targets.cpp_compile.label,
+    ])
+    build_setting.env().entries().contains_exactly({"APPLE_MIN_OS": _OVERRIDDEN_MIN_OS})
+
+    converted = env.expect.that_value(
+        convert_args(targets.build_setting_format_override[ArgsInfo]),
+        factory = _CONVERTED_ARGS,
+    )
+    converted.env_sets().contains_exactly([env_set(
+        actions = ["c_compile", "cpp_compile"],
+        env_entries = [env_entry(key = "APPLE_MIN_OS", value = _OVERRIDDEN_MIN_OS)],
+    )])
+    converted.flag_sets().contains_exactly([flag_set(
+        actions = ["c_compile", "cpp_compile"],
+        flag_groups = [flag_group(flags = [_OVERRIDDEN_MIN_OS])],
+    )])
+
 TARGETS = [
     ":simple",
     ":some_variable",
     ":env_only",
     ":env_only_requires",
     ":build_setting_format",
+    ":build_setting_format_override",
     ":with_dir",
     ":with_dir_and_data",
     ":iterate_over_optional",
@@ -384,6 +407,7 @@ TESTS = {
     "with_dir_test": _with_dir_test,
     "with_dir_and_data_test": _with_dir_and_data_test,
     "build_setting_format_test": _build_setting_format_test,
+    "build_setting_format_override_test": _build_setting_format_override_test,
     "good_env_format_test": _good_env_format_test,
     "good_env_format_optional_test": _good_env_format_optional_test,
 }

tests/rule_based_toolchain/args/override_args.bzl

@@ -0,0 +1,48 @@
+# Copyright 2024 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+"""Test-only helper to apply a build setting override."""
+
+load("//cc/toolchains:cc_toolchain_info.bzl", "ArgsInfo", "ArgsListInfo")
+
+_MIN_OS_FLAG = "//tests/rule_based_toolchain/args:macos_min_os_flag"
+
+def _override_min_os_transition_impl(settings, attr):
+    return {_MIN_OS_FLAG: attr.value}
+
+_override_min_os_transition = transition(
+    implementation = _override_min_os_transition_impl,
+    inputs = [],
+    outputs = [_MIN_OS_FLAG],
+)
+
+def _override_args_impl(ctx):
+    target = ctx.attr.target
+    if type(target) == "list":
+        target = target[0]
+    return [
+        target[ArgsInfo],
+        target[ArgsListInfo],
+    ]
+
+override_args = rule(
+    implementation = _override_args_impl,
+    attrs = {
+        "target": attr.label(
+            cfg = _override_min_os_transition,
+            providers = [ArgsInfo],
+            mandatory = True,
+        ),
+        "value": attr.string(mandatory = True),
+    },
+)