advent_of_code_2017/Day18Part2Program.cfc at master · rellem/advent_of_code_2017 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
<cfcomponent output="false">

	<cffunction name="runAndReturnNumSentValues" access="public" returntype="numeric" output="false">
		<cfargument name="input" type="string" required="true" />
		<cfargument name="outQueue" type="Queue" required="true" />
		<cfargument name="inQueue" type="Queue" required="true" />
		<cfargument name="initialRegisterValues" type="struct" required="true" />

		<cfset javaMath = CreateObject('java', 'java.lang.Math') />

		<cfset var instructions = [] />
		<cfset var line = '' />
		<cfloop list="#arguments.input#" item="line" delimiters="#Chr(10)#">
			<cfset ArrayAppend(instructions, ListToArray(Trim(line), Chr(32))) />
		</cfloop>

		<cfset variables.registers = StructCopy(arguments.initialRegisterValues) />

		<cfset var numSentValues = 0 />

		<cfset var ip = 1 />
		<cfset var instruction = '' />
		<cfloop condition="ip gte 1 && ip lte #ArrayLen(instructions)#">
			<cfset instruction = instructions[ip] />
			<cfswitch expression="#instruction[1]#">
				<cfcase value="add">
					<cfset setRegisterValue(instruction[2], javaMath.addExact(getRegisterValue(instruction[2]), getValue(instruction[3]))) />
				</cfcase>
				<cfcase value="jgz">
					<cfif getValue(instruction[2]) gt 0>
						<cfset ip += getValue(instruction[3]) - 1 />
					</cfif>
				</cfcase>
				<cfcase value="mod">
					<cfset setRegisterValue(instruction[2], javaMath.floorMod(getRegisterValue(instruction[2]), getValue(instruction[3]))) />
				</cfcase>
				<cfcase value="mul">
					<cfset setRegisterValue(instruction[2], javaMath.multiplyExact(getRegisterValue(instruction[2]), getValue(instruction[3]))) />
				</cfcase>
				<cfcase value="rcv">
					<cftry>
						<cfset setRegisterValue(instruction[2], arguments.inQueue.poll(timeoutInMilliseconds = 1000)) />
						<cfcatch type="Queue.PollTimeout">
							<cfbreak />
						</cfcatch>
					</cftry>
				</cfcase>
				<cfcase value="set">
					<cfset setRegisterValue(instruction[2], getValue(instruction[3])) />
				</cfcase>
				<cfcase value="snd">
					<cfset arguments.outQueue.add(getValue(instruction[2])) />
					<cfset numSentValues++ />
				</cfcase>
				<cfdefaultcase>
					<cfthrow message="Unexpected mnemonic: #instruction[1]#" />
				</cfdefaultcase>
			</cfswitch>

			<cfset ip++ />
		</cfloop>

		<cfreturn numSentValues />
	</cffunction>

	<cffunction name="setRegisterValue" access="private" returntype="void" output="false">
		<cfargument name="register" type="string" required="true" />
		<cfargument name="value" type="numeric" required="true" />

		<cfset variables.registers[arguments.register] = CreateObject('java', 'java.lang.Long').init(arguments.value) />
	</cffunction>

	<cffunction name="getRegisterValue" access="private" returntype="numeric" output="false">
		<cfargument name="register" type="string" required="true" />

		<cfreturn variables.registers[arguments.register] />
	</cffunction>

	<cffunction name="getValue" access="private" returntype="numeric" output="false">
		<cfargument name="valueOrRegister" type="string" required="true" />

		<cfif IsNumeric(arguments.valueOrRegister)>
			<cfreturn CreateObject('java', 'java.lang.Long').init(arguments.valueOrRegister) />
		</cfif>

		<cfreturn getRegisterValue(arguments.valueOrRegister) />
	</cffunction>

</cfcomponent>